home *** CD-ROM | disk | FTP | other *** search
/ Language/OS - Multiplatform Resource Library / LANGUAGE OS.iso / dsp / dr.bub / 96000.lha / 96000 / appb / b124.asm < prev    next >
Assembly Source File  |  1992-04-28  |  4KB  |  72 lines
  1. ; This program was originally published in the Motorola DSP96002 Users Manual
  2. ; and is provided under a DISCLAIMER OF WARRANTY available from Motorola DSP
  3. ; Operation, 6501 William Cannon Drive West, Austin, Texas 78735-8598.  For
  4. ; more information, refer to the DSP96002 Users Manual, Appendix B, DSP
  5. ; Benchmarks.
  6. ;
  7. ; B.1.24    Table Lookup with Linear Interpolation Between Points  
  8. ;This performs a table lookup and linear interpolation between points in  the table.  It is assumed that 
  9. ;the spacing between the known values  (breakpoints) is a constant.  No range checking is  per-
  10. ;formed on the input number because it is assumed that previous  calculations may have limiting and 
  11. ;range checking.  This can be used to  approximate arbitrary functions given a set of known points 
  12. ;(such as  digital sine wave generation) or to interpolate linearly between values  of a set of data such 
  13. ;as an image.  
  14. ;The function to be approximated is shown below:  
  15. ; 
  16. ;                                 o           ? known values of function 
  17. ;                          o             o 
  18. ;   Y(i)            o 
  19. ;         
  20. ;            o 
  21. ;        ----+------+------+------+------+ 
  22. ;  X(i)?   1.0    6.0   11.0   16.0   21.0   ? indexes 
  23. ;            ^         / spacing between indexes is INDSPC, 5.0 
  24. ;                         in this example 
  25. ;              
  26. ;           FIRSTINDEX - value of the first index in the table, 1.0 
  27. ;                        in this example 
  28. ;
  29. ;Given an input value "x", the linearly interpolated value "y"  from the tabulated known values is:  
  30. ;        Y(i+1)-Y(i) 
  31. ;   y = --------------(x-X(i)) + Y(i) 
  32. ;        X(i+1)-X(i) 
  33. ;
  34. ;                                                            Program    ICycles
  35. ;                                                            Words 
  36. ; 
  37. ;     Approximate d4=exp(d0) for 1.0 <= x <= 21.0 
  38. ; 
  39.      page     132,60,1,1 
  40.      org     x:0 
  41. table     dc     2.7182818e+00          ;exp(1.0) 
  42.           dc     4.0342879e+02          ;exp(6.0) 
  43.           dc     5.9874141e+04          ;exp(11.0) 
  44.           dc     8.8861105e+06          ;exp(16.0) 
  45.           dc     1.3188157e+09          ;exp(21.0) 
  46.  
  47.      org     p:$50 
  48. firstindex equ    1.0         ;value of first table index 
  49. indspc     equ    5.0         ;index spacing 
  50. rindspc    equ    1.0/indspc  ;reciprocal of index spacing 
  51.  
  52.   move    #table,n0        ;point to start of table 
  53.   move    #firstindex,d6.s ;value of first index 
  54.   move    #rindspc,d7.s    ;reciprocal of index spacing 
  55.  
  56.   fsub.s  d6,d0          ;adjust input relative to index      1     1 
  57.   fmpy.s  d7,d0,d0       ;reduce range and create index       1     1 
  58.   floor   d0,d1          ;get index                           1     1 
  59.   int     d1   d1.s,d2.s ;convert index to int,copy int part  1     1 
  60.   fsub.s  d2,d0  d1.l,r0 ;x-X(i), get ptr to table            1     1 
  61.   nop                    ;clear address ALU pipe              1     1 
  62.   move    (r0)+n0        ;point to Y(i)                       1     1 
  63.   move    x:(r0)+,d4.s   ;get Y(i)                            1     1 
  64.   move    x:(r0),d5.s    ;get Y(i+1)                          1     1 
  65.   fsub.s  d4,d5          ;Y(i+1)-Y(i)                         1     1 
  66.   fmpy.s  d0,d5,d5       ; *(x-X(i))                          1     1 
  67.   fadd.s  d5,d4          ;+Y(i)                               1     1 
  68. ;                                                             ---   --- 
  69. ;                                                     Totals:  12    12 
  70.  
  71.  
  72.